HELP ME ! Mạch đếm sản phẩm lập trình = asem

[quangdao]

Tôi mới học về ngôn ngữ asem ,mà thầy giáo đã giao cho 1 bài tập lớn là thiết kế một mạch đếm sản phẩm (giới hạn khoảng 100sp) bao gồm cả phần cứng (dùng IC họ 8051) lẫn phần mềm (viết = asembly) .Tôi tìm trên mạng suốt mà chẳng có cái nào tương tự cả.
Mong mọi người giúp đỡ tôi với.

[irf540]

bạn có thể làm như sau :
dùng một mạch tạo xung 38khz để phát tín hiệu hồng ngoại .
dùng con thu TL1738 để làm con thu.
chân out của TL1738 đưa qua tầng đảo (1 chú tranzitor) rồi đưa vào chân ngắt ngoài của 8051.
khi không có sản phẩm đi qua TL1738 nhận được tín hiệu chân out của nó lúc này ở mức logic 0 qua tầng đảo sẽ là mức logic 1.
khi có sản phẩm đi qua TL1738 không nhận được tín hiệu chân out của nó ở mức logic 1 qua tầng đảo bạn sẽ có mức logic 0. tại chân ngắt lúc này có cạnh xuống 8051 sẽ ngắt (nếu đặt chế đọ ngắt là cạnh xuống tại chân ngắt ngoài) bạn tăng giá trị của sản phẩm lên (nên dùng thêm timer ngắt chỗ này để khống chế nhiễu).
phần hiển thị bạn có thể dùng led 7 đoạn. vì chỉ hiện tới 100 thôi nên bạn có thể kết nối từng port riêng cũng được cho đỡ mất công.
phần cảm biến như thế này sẽ không bị nhiễu bởi ánh sáng môi trường.
còn tại sao vẫn nên dùng timer ngắt kết hợp ngắt ngoài để chống nhiễu cái gì bạn nên thử đi rồi sẽ hiểu.

[namqn]

Tôi mới học về ngôn ngữ asem ,mà thầy giáo đã giao cho 1 bài tập lớn là thiết kế một mạch đếm sản phẩm (giới hạn khoảng 100sp) bao gồm cả phần cứng (dùng IC họ 8051) lẫn phần mềm (viết = asembly) .Tôi tìm trên mạng suốt mà chẳng có cái nào tương tự cả.
Mong mọi người giúp đỡ tôi với.

Tùy loại sản phẩm mà bạn có cách cảm nhận, và từ đó đếm nó, một cách thích hợp.

Chẳng hạn, cách dùng hồng ngoại để phát hiện có vật đi ngang làm gián đoạn tín hiệu giữa bộ thu và phát hồng ngoại là một cách. Nhưng nó có thể không hoạt động nếu bạn cần đếm những vật trong suốt, và giải pháp đó cũng khá tốn kém.

Người ta cũng có thể dùng các cảm biến cơ học, như các micro switch được bố trí thích hợp trên đường đi của sản phẩm.

Một vài ví dụ để bạn thấy rằng đầu bài chưa đủ.

Thân,

[cong_ty]

Tôi mới học về ngôn ngữ asem ,mà thầy giáo đã giao cho 1 bài tập lớn là thiết kế một mạch đếm sản phẩm (giới hạn khoảng 100sp) bao gồm cả phần cứng (dùng IC họ 8051) lẫn phần mềm (viết = asembly) .Tôi tìm trên mạng suốt mà chẳng có cái nào tương tự cả.
Mong mọi người giúp đỡ tôi với.

Ặc, làm bộ đếm sản phẩm nếu làm đàng hoàng một tí thì không đơn giản chút nào đâu. Một số điểm bạn cần lưu ý nhé: viết bằng asembly hay C thì không quan trọng cái quan trọng là bạn phải chú ý tới sản phẩm cần đếm, chẳng hạn như bạn đếm mấy bao tải hàng trên băng tải do công nhân bốc xếp đặt lên thì sẽ có lúc bao bị đè lên nhau, lúc đó dùng cảm biến hồng ngoại hay micro switch thì cũng khó giải quyết. Thứ hai là lỡ băng chuyền bị ngừng đột ngột, bao tải dùng ngay cảm biến, nếu dùng ngắt và timer ư , suy nghĩ kĩ một chút là có vấn đề xảy ra đó . Tôi chỉ đơn cử hai ví dụ thôi. Còn bạn làm bài tập lớn thì nói chung là cưỡi ngựa xem hoa cũng được điểm cao , hehehe

[HueDN]

Tôi gửi cho bạn 2 phần trên file đính kèm:
Phần 1 dùng các IC logic bình thường
Phần 2 dùng vi điều khiển
Chúc thành công

[HueDN]

Tại sao không đính kèm file được nhỉ
Thế thì tôi đưa chỉ phần chương trình thôi nhé, rất tiếc
Chöông III: MAÕ NGUOÀN CHÖÔNG TRÌNH
MAÙY ÑEÁM SAÛN PHAÅM

;************************************************* ******
;******** CHUONG TRINH MAY DO DEM SAN PHAM *************
; Ngay hoan thanh: 26/11/2001
; HIEU CHINH : 27 - 11 - 2001
;************************************************* ******
; Phan Cong Hue. Hoatho Textile and Garment Company
;************************************************* ******
; Chuong trinh cho phep nhap L1,L2. Hien thi, so sanh, ;luu.Nhap L1 > L2. Reset so dem khi den L1. Luu: Cong ;vao bien san pham tung ca sau moi 100 met. Xem san ;pham: Hien thi san pham X1000, co phan thap phan
;*********************** KHAI BAO **********************
CHONLED EQU 4000H ;PORT A 8255
XUATLED EQU 4001H ;PORT B 8255
XUATRA EQU 4002H ;PORT C 8255
CWR EQU 4003H ;TU DIEU KHIEN 8255
BYTECAO EQU 3FH
BYTETHAP EQU 3EH
MODE EQU 3DH
CA EQU 3CH
MANHAP EQU 3BH
L2H DATA 35H
L2L DATA 34H
L1H DATA 33H
L1L DATA 32H
SPH DATA 31H
SPL DATA 30H
SPCA1L DATA 2FH
SPCA1H DATA 2EH
SPCA2L DATA 2DH
SPCA2H DATA 2CH
SPCA3L DATA 2BH
SPCA3H DATA 2AH
SPCA4L DATA 29H
SPCA4H DATA 28H
SPHH DATA 27H
TPHAN DATA 26H ; Dau phay thap phan
BITF BIT 9FH
BITE BIT 9EH
BITD BIT 9DH
BITC BIT 9CH
BITB BIT 9BH
BITA BIT 9AH
BITSO BIT 99H
BITCO BIT 98H
;************************************************* ******
;***************** CHUONG TRINH CHINH ******************
;************************************************* ******
ORG 0000H
LJMP BATDAU
LJMP EX0ISR ; Ngat ngoai 0 phuc vu Ban
ORG 000BH ;phim Nhap so lieu
LJMP T0ISR ; Hien thi L1,L2
ORG 0013H
LJMP EX1ISR ; Ngat ngoai 1 phuc vu bao
ORG 001BH ;ve Du lieu
LJMP T1ISR ; Ngat T1 phuc vu Hien thi
ORG 0030H
BATDAU: MOV SP,#4FH ; Dinh vung Stack
MOV TMOD,#10101B ; T1(16BIT),T0(Dem su kien)
MOV IE,#8FH ; Cho phep T0,T1,INT1,INT0
SETB IP.3 ; Uu tien ngat T1 H-thi
SETB TF1 ; Ngat dau tien cua T1
SETB IT0 ; Ngat kich khoi muc am
SETB TR0 ; Cho phep do dem san pham
BATDAU0: CLR P3.0 ; Tat den tin hieu L2
CLR P3.1 ; Ngat Role bao day L1
CLR P3.5
MOV SPH,#00H
MOV SPL,#00H
MOV BYTETHAP,#00H
MOV BYTECAO,#00H
MOV TPHAN,#00H
BATDAU1: MOV SPHH,#00H
MOV TL0,#00H
BATDAU2: MOV A,TL0
LCALL DOISO
MOV SPL,A
MOV A,SPHH
LCALL DOISO
MOV SPH,A
LCALL INHEX
JNB BITCO,BATDAU3 ; Co phim nhan?
LCALL PHATHIEN
CAA: JNB BITA,CAB ; La CA 1 ?
MOV CA,#01H
SJMP BATDAU3
CAB: JNB BITB,CAC ; La CA 2 ?
MOV CA,#02H
SJMP BATDAU3
CAC: JNB BITC,CAD ; La CA 3 ?
MOV CA,#03H
SJMP BATDAU3
CAD: JNB BITD,XEM ; La CA 4 ?
MOV CA,#04H
SJMP BATDAU3
XEM: JNB BITE,RESETCOUNT ; Xem san pham tung ca?
LCALL XEMSP
SJMP BATDAU3
RESETCOUNT: JNB BITF,BATDAU3 ; Xoa san pham hien hanh
MOV TL0,#00H
MOV SPHH,#00H
MOV SPL,#00H
MOV SPH,#00H
SJMP BATDAU3
BATDAU3: LCALL DEM
JB P3.0,BATDAU4 ; P3.0 muc cao
MOV A,SPH
CJNE A,L2H,BATDAU2
MOV A,SPL
CJNE A,L2L,$+3
JC BATDAU2
SETB P3.0 ; Bat den tin hieu L2
BATDAU4: MOV A,SPH
CJNE A,L1H,$+3
JC BATDAU2
MOV A,SPL
CJNE A,L1L,$+3
JC BATDAU2
SETB P3.1 ; Dong Role bao day L1
LCALL DL500
LJMP BATDAU0
;************************************************* ******
;*************** CAC CHUONG TRINH CON ******************
;************************************************* ******
;*************** CHUONG TRINH DELAY 4mS ****************
DELAY4 : PUSH 02H
PUSH 03H
MOV R2, #08H
LD1: MOV R3, #0FFH
LD2: DJNZ R3, LD2
DJNZ R2, LD1
POP 03H
POP 02H
RET
;*************** CHUONG TRINH DELAY 500mS *************
DL500: PUSH 02H
PUSH 03H
MOV R2, #250
LD3: MOV R3, #250
DJNZ R3, $
MOV R3,#250
DJNZ R3, $
DJNZ R2, LD3
MOV R2,#250
LD4: MOV R3, #250
DJNZ R3, $
MOV R3,#250
DJNZ R3,$
DJNZ R2,LD4
POP 03H
POP 02H
RET
;********************* IN-HEX *************************
INHEX: MOV R4,#50
BACK1: LCALL GETKEY
JNC QUITHEX
DJNZ R4,BACK1
PUSH ACC
BACK2: MOV R4,#50
BACK3: LCALL GETKEY
JC BACK2
DJNZ R4,BACK3
POP ACC
QUITHEX: RET
;************************************************* ******
GETKEY: MOV A,#0FEH
MOV R6,#4
TEST: MOV P1,A
MOV R7,A
MOV A,P1
ANL A,#0F0H
CJNE A,#0F0H,KEYHIT
MOV A,R7
RL A
DJNZ R6,TEST
CLR C
SJMP EXIT
KEYHIT: MOV R7,A
MOV A,#4
CLR C
SUBB A,R6
MOV R6,A
MOV A,R7
SWAP A
MOV R5,#4
AGAIN: RRC A
JNC DONE
INC R6
INC R6
INC R6
INC R6
DJNZ R5,AGAIN
DONE: SETB C
MOV BITCO,C
MOV MANHAP,R6
ANL MANHAP,#0FH ; Xoa 4 bit cao
EXIT: RET
;**************** CHUONG TRINH DEM SAN PHAM ************
DEM: CLR C
MOV A,TL0
CJNE A,#100,EXIT1 ; Du 100 ?
JC EXIT1 ; (Cho dem nhanh)
MOV SPL,#00H
MOV TL0,#00H
LCALL LUU ; Luu sau moi 100 met
INC SPHH
MOV A,SPHH
CJNE A,#100,EXIT1 ; Du 10000 ?
MOV SPH,#00H
MOV SPHH,#00H
MOV SPL,#00H
MOV TL0,#00H
EXIT1: CLR C
CLR AC
RET
;**************** CHUONG TRINH LUU SAN PHAM ************
LUU: CLR C
PUSH ACC
MOV A,CA
SHIFTA: CJNE A,#01H,SHIFTB ; La san pham ca A?
INC SPCA1L
MOV A,SPCA1L
CJNE A,#100,$+3
JC EXITLUU
MOV SPCA1L,#00H
INC SPCA1H
LJMP EXITLUU
SHIFTB: CJNE A,#02H,SHIFTC ; La san pham ca B?
INC SPCA2L
MOV A,SPCA2L
CJNE A,#100,$+3
JC EXITLUU
MOV SPCA2L,#00H
INC SPCA2H
LJMP EXITLUU
SHIFTC: CJNE A,#03H,SHIFTD ; La san pham ca C?
INC SPCA3L
MOV A,SPCA3L
CJNE A,#100,$+3
JC EXITLUU
MOV SPCA3L,#00H
INC SPCA3H
LJMP EXITLUU
SHIFTD: CJNE A,#04H,EXITLUU ; La san pham ca D?
INC SPCA4L
MOV A,SPCA4L
CJNE A,#100,$+3
JC EXITLUU
MOV SPCA4L,#00H
INC SPCA4H
EXITLUU: POP ACC
RET
;***************** CHUONG TRINH XEM SAN PHAM ***********
XEMSP: PUSH ACC
PUSH TMOD
PUSH DPH
PUSH DPL
SETB P3.5
SETB P3.1 ; Ngung may de xem
CLR TR1 ; Ngat hien thi san pham
MOV TMOD,#10001B ; T1(16BIT),T0(16Bit-Timer)
SETB IP.1 ; Uu tien cho hien thi
SETB TF0 ; Ngat dau tien cua T0
MOV TPHAN,#01H
ROTA: LCALL INHEX
JNB BITCO,ROTA ; Co nhan ? Tiep tuc
LCALL PHATHIEN
JB BITF,EXIT10 ; Phim F Thoat
JB BITE,EXIT9 ; Phim E Xoa san pham 4 Ca
JNB BITA,XSP2 ; Phim A ?
MOV MODE,#01H ; Hien thi san pham ca A
MOV A,SPCA1L
LCALL DOISO
MOV BYTETHAP,A
MOV A,SPCA1H
LCALL DOISO
MOV BYTECAO,A
XSP2: JNB BITB,XSP3 ; Phim B ?
MOV MODE,#02H ; Hien thi san pham ca B
MOV A,SPCA2L
LCALL DOISO
MOV BYTETHAP,A
MOV A,SPCA2H
LCALL DOISO
MOV BYTECAO,A
XSP3: JNB BITC,XSP4 ; Phim C ?
MOV MODE,#03H ; Hien thi san pham ca C
MOV A,SPCA3L
LCALL DOISO
MOV BYTETHAP,A
MOV A,SPCA3H
LCALL DOISO
MOV BYTECAO,A
XSP4: JNB BITD,EXIT8 ; Phim D ?
MOV MODE,#04H ; Hien thi san pham ca D
MOV A,SPCA4L
LCALL DOISO
MOV BYTETHAP,A
MOV A,SPCA4H
LCALL DOISO
MOV BYTECAO,A
EXIT8: LJMP ROTA
EXIT9: MOV SPCA1L,#00H ;
MOV SPCA1H,#00H ;
MOV SPCA2L,#00H ;
MOV SPCA2H,#00H ; Xoa san pham tat ca
MOV SPCA3L,#00H ;4 Ca san xuat
MOV SPCA3H,#00H ;
MOV SPCA4L,#00H ;
MOV SPCA4H,#00H ;
EXIT10: SETB TR1 ; Cho Hien thi binh thuong
SETB P3.2
CLR P3.1 ; Ngat Role L1
CLR P3.5
MOV BYTETHAP,#00H
MOV BYTECAO,#00H
MOV TPHAN,#00H
POP DPL
POP DPH
POP TMOD
POP ACC
RET
;******************* PHAT HIEN PHIM ********************
PHATHIEN: CLR BITA ; Ma 0AH
CLR BITB ; Ma 0BH
CLR BITC ; Ma 0CH
CLR BITD ; Ma 0DH
CLR BITE ; Ma 0EH
CLR BITF ; Ma 0FH
CLR BITCO
MOV A,MANHAP
CJNE A,#0FH,PH1 ; Phim F ?
SETB BITF
SJMP EXIT5
PH1: CJNE A,#0EH,PH2 ; Phim E ?
SETB BITE
SJMP EXIT5
PH2: CJNE A,#0DH,PH3 ; Phim D ?
SETB BITD
SJMP EXIT5
PH3: CJNE A,#0CH,PH4 ; Phim C ?
SETB BITC
SJMP EXIT5
PH4: CJNE A,#0BH,PH5 ; Phim B ?
SETB BITB
SJMP EXIT5
PH5: CJNE A,#0AH,PH6 ; Phim A ?
SETB BITA
SJMP EXIT5
PH6: CLR C
CJNE A,#0AH,$+3 ; Phim SO ?
JNC EXIT5
SETB BITSO
EXIT5: RET
;***************** CHUONG TRINH NHAP SO LIEU ***********
NHAPSO: LCALL INHEX
JNB BITCO,NHAPSO
LCALL PHATHIEN
JNB BITSO,NHAPSO
MOV R0,#4
NS1: CLR C
MOV A,BYTETHAP
RLC A
MOV BYTETHAP,A
MOV A,BYTECAO
RLC A
MOV BYTECAO,A
DJNZ R0,NS1
MOV A,BYTETHAP
ORL A,MANHAP
MOV BYTETHAP,A
LCALL DL500
RET
;********************* NHAP L1 *************************
NHAPL1: CLR BITD
MOV MODE,#01H
MOV BYTETHAP,L1L
MOV BYTECAO,L1H
NH11: LCALL INHEX
LCALL PHATHIEN
JB BITC,NH13 ; Phim Enter, Thoat
JB BITE,NH13 ; Phim L2, Thoat
JNB BITF,NH11 ; Phim Clear, Tiep tuc
CLR BITF
MOV BYTETHAP,#00H
MOV BYTECAO,#00H
MOV R1,#04H
QUAY0: LCALL NHAPSO
DJNZ R1,QUAY0
NH12: LCALL INHEX
LCALL PHATHIEN
JB BITF,NH14 ; Phim Clear, Khong nhap
JNB BITC,NH12 ; Cho Phim Enter, Nhap
NH13: MOV L1L,BYTETHAP
MOV L1H,BYTECAO
NH14: RET
;********************* NHAP L2 *************************
NHAPL2: CLR BITE
MOV MODE,#02H
MOV BYTETHAP,L2L
MOV BYTECAO,L2H
NH21: LCALL INHEX
LCALL PHATHIEN
JB BITC,NH23 ; Phim Enter, Thoat
JB BITD,NH23 ; Phim L1, Thoat
JNB BITF,NH21 ; Phim Clear, Tiep tuc
CLR BITF
MOV BYTETHAP,#00H
MOV BYTECAO,#00H
MOV R1,#04H
QUAY2: LCALL NHAPSO
DJNZ R1,QUAY2
NH22: LCALL INHEX
LCALL PHATHIEN
JB BITF,NH24 ; Phim Clear, Khong nhap
JNB BITC,NH22 ; Cho Phim Enter, Nhap
NH23: MOV L2L,BYTETHAP
MOV L2H,BYTECAO
NH24: RET
;****************** CHUONG TRINH DOI SO ***************
DOISO: MOV B,#10
DIV AB
ANL A,#0FH
SWAP A
ORL A,B
RET
;************ CHUONG TRINH DOI SO HEX RA BCD **********
DOISO1: MOV B,#10
DIV AB
PUSH B
MOV B,#10
DIV AB
MOV A,B
SWAP A
POP B
ORL A,B
RET
;*** CHUONG TRINH PHUC VU NGAT NGOAI 0 - NHAP SO LIEU **
EX0ISR: PUSH ACC ; P3.2=0
PUSH TMOD
CLR TR1 ; Ngat hien thi san pham
MOV TMOD,#10001B ; T1(16BIT),T0(16Bit-Timer)
SETB IP.1 ; Uu tien cho hien thi
SETB TF0 ; Ngat dau tien cua T0
SETB P3.1 ; Ngung may
QUAY3: LCALL INHEX
JNB BITCO,QUAY3 ; Co nhan ? Tiep tuc
LCALL PHATHIEN
JB BITF,EXIT4 ; Phim F Thoat
JNB BITD,NN0 ; Phim L1 ? Nhap L1
LCALL NHAPL1
NN0: JNB BITE,EXIT3 ; Phim L2 ? Nhap L2
LCALL NHAPL2
EXIT3: LJMP QUAY3
EXIT4: SETB TR1 ; Cho Hien thi binh thuong
SETB P3.2
CLR P3.1 ; Ngat Role L1
POP TMOD
POP ACC
RETI
;******* CHUONG TRINH NGAT PHUC VU HIEN THI L1,L2 ******
T0ISR: PUSH ACC
PUSH PSW
CLR TR0 ; Ngung bo dem 0
MOV TH0,#HIGH(-10000) ; Nap gia tri cho bo dem
MOV TL0,#LOW(-10000) ; Dung thach anh 12 MHz
MOV DPTR,#CWR ; Tan so hien thi 100 Hz
MOV A,#80H ; Khoi dong 8255
MOVX @DPTR,A
MOV DPTR,#XUATRA ; Cong PC0 cao
MOV A,TPHAN
MOVX @DPTR,A
LCALL DELAY4
MOV DPTR, #CHONLED ; Hien thi Bytethap
MOV A,#1
MOVX @DPTR, A
MOV DPTR, #XUATLED
MOV A,BYTETHAP
MOVX @DPTR, A
LCALL DELAY4
MOV DPTR, #CHONLED ; Hien thi Bytecao
MOV A, #2
MOVX @DPTR, A
MOV DPTR, #XUATLED
MOV A,BYTECAO
MOVX @DPTR, A
LCALL DELAY4
MOV DPTR, #CHONLED ; Hien thi Mode
MOV A, #4
MOVX @DPTR, A
MOV DPTR, #XUATLED
MOV A,MODE
MOVX @DPTR, A
LCALL DELAY4
MOV DPTR,#CHONLED
MOV A,#0H
MOVX @DPTR,A
SETB TR0 ; Cho bo dem chay
POP PSW
POP ACC
RETI
; CHUONG TRINH PHUC VU NGAT NGOAI 1 - NGUON GIAM PD
EX1ISR: PUSH DPH
PUSH DPL
PUSH ACC
PUSH PSW
ORL 87H,#10B ; Set bit nguon giam PD
RETI
;************* CHUONG TRINH HIEN THI *******************
T1ISR: PUSH ACC
PUSH PSW
CLR TR1 ; Ngung bo dem 1
MOV TH1,#HIGH(-10000) ; Nap gia tri cho bo dem
MOV TL1,#LOW(-10000) ; Dung thach anh 12 MHz
MOV DPTR,#CWR ; Tan so hien thi 100 Hz
MOV A,#80H
MOVX @DPTR,A
MOV DPTR, #CHONLED ;HIEN THI BYTE LED1
MOV A,#1
MOVX @DPTR, A
MOV DPTR, #XUATLED
MOV A,SPL
MOVX @DPTR, A
LCALL DELAY4
MOV DPTR, #CHONLED ; Hieån thò BYTE LED2
MOV A, #2
MOVX @DPTR, A
MOV DPTR, #XUATLED
MOV A,SPH
MOVX @DPTR, A
LCALL DELAY4
MOV DPTR, #CHONLED ; Hieån thò BYTE LED4
MOV A, #8
MOVX @DPTR, A
MOV DPTR, #XUATLED
MOV A,CA
MOVX @DPTR, A
LCALL DELAY4
MOV DPTR,#CHONLED
MOV A,#0H
MOVX @DPTR,A
SETB TR1 ; Cho bo dem chay
POP PSW
POP ACC
RETI
END

[quangdao]

Cảm ơn các bạn , nhưng mà đề bài mà thầy giáo mình ra chỉ có như vậy thôi.
Còn việc sử dụng loại cảm biến nào, đếm loại sản phẩm như thế nào thì lại phải tự mình đưa ra quyết định (ban đầu thì mình định dùng cảm biến ánh sáng để đếm những sản phẩm bình thường có cản sáng thôi).Nhưng sau khi "irf540" góp ý "phần cảm biến như thế này sẽ không bị nhiễu bởi ánh sáng môi trường" mình quyết định sẽ làm theo cách mà irf540 gợi ý.và mình cũng cảm ơn HueDN đã post lên mã nguồn ,mình sẽ thử .

[HueDN]

Bạn vào hộp thư:
avrfans.vn@gmail.com
(password: avrfans)
để có chi tiết hơn.

[schanbkhn]

mấy bác có thể gửi cho em sơ đò mạch được không ạ
em đang cần ....

địa chỉ email của em là chanbkhn@yahoo.com

Cám ơn các bác nhiều lắm !

[kiencon]

can mach dem san pham GAP!!

minh đang bí phần thu phát hồng ngoại,không biết dùng con gì,lắp ráp ra sao,bạn nào có cho mình xin để gắn vào phần đếm sản phẩm
yahoomail của mình là : minhnhut_na@yahoo.com

[phucthinhel]

nếu bạn có chút tiền thì bạn có thể ra Nhật Tảo mua cho cảm biến hồng ngoại dạng thu phát phản xạ là tốt nhất còn không dùng con thu phát dạng rẽ tiền giá Nhật Tảo khoảng 7K thui ( phải chế mạch dao động lung tung ! he he hàng rẽ mà ) . Còn chân out nó dùng phép ngắt thì mọi chuyện sẽ không rắc rối lắm đâu mà lại chính xác nữa ! À mà nhớ dùng phép ngắt cạnh nhé ! vì sao thì tự tìm hiểu nhé ! Phân tích !

[hoangnam3.0]

thanhs bac nhieu lam

Bac hueDN oi, bác có thể nói chi tiết hơn về để tài của bác cũng như phần cứng được không ạ! Em xem ma chưa hiểu được nhiều về ý tưởng của bác.

[Nin]

em lưu số đếm đc trong R0 (giới hạn đếm có 99 thôi), mấy anh cho em sơ đồ kết nối và đoạn code asamble xuất số đếm ra 2 con led 7s nhe, cám ơn nhiều.

[hightech_uc]

Nếu muốn xịn thì nên dùng con thu 3 chân của OMRON, nó lọc nhiễu tốt lắm, tuy nhiên để đảm bảo chính xác vẫn cần lọc nhiễu bằng phần mềm nữa đấy..Cần code lọc nhiễu bằng time liên hệ tôi gửi cho...Ko nhất định phải đưa vào chân couter hay ngắt ngoài đâu...

[Nin]

uhm, bạn cho mình xin với mail mình là yuunin@gmail.com