[Help-Khẩn cấp] Code ASM led 7 đoạn qua 89c51 + 7447 + 74138

[nhokiki]

Anh chị ơi cho em hỏi : Nếu như e chỉ dùng 1 port của VĐK (8051-P2) để hiển thị đếm 4 led 7 đoạn. Em muốn dùng 4 bit thấp để xuất ra IC giải mã 7447, còn 3 bit cao để điều khiển IC giải mã 74LS138 để quét led . Nhưng em chưa đc thành thạo việc xuất ra 4 bit thấp mà không bị ảnh hưởng đến 4 bit cao. Anh chị có code nào chơem thao khảo với ạ ? Em cám ơn nhiều!

[tramng]

Code cho bạn tham khảo nhé : đếm với counter ngoài (counter 0) từ 000 đến 255

    TRAM            EQU    20H
    CHUC            EQU    21H
    DONVI           EQU    22H

    MTRAM        EQU    30H
    MCHUC        EQU    31H
    MDONVI       EQU    32H    

    ORG    0000H
    
    MOV        DPTR,#MA7447
    MOV        TMOD,#05H
    SETB       TR0
    CLR         TF0
MAIN:
    LCALL        HEXTOBCD
    LCALL        GIAIMA
    LCALL        DELAY_HIENTHI
    JMP           MAIN

HEXTOBCD:
    MOV        A,TL0
    MOV        B,#10
    DIV         AB            ; CHIA LAN 1 
    MOV        DONVI,B        ; LUU BCD_DVI VAO ON 20H 
    
    MOV        B,#10 
    DIV         AB            ; CHIA LAN 2 
    
    MOV        CHUC,B        ; LUU BCD_CHUC VAO ON 21H 
    
    MOV        TRAM,A        ; LUU BCD_TRAM VAO ON 22H 
RET

GIAIMA:
    MOV          A,DONVI
    MOVC        A,@A+DPTR
    MOV          MDONVI,A
    ANL           MDONVI,#3FH

    MOV          A,CHUC
    MOVC        A,@A+DPTR
    MOV          MCHUC,A
    ANL           MCHUC,#2FH

    MOV          A,TRAM
    MOVC        A,@A+DPTR
    MOV          MTRAM,A
    ANL           MTRAM,#1FH
RET

HIENTHI:  
    MOV          P2,MDONVI
    LCALL        DELAY510US
    MOV          P2,#00H

    MOV          P2,MCHUC
    LCALL        DELAY510US
    MOV          P2,#00H

    MOV          P2,MTRAM
    LCALL        DELAY510US
    MOV          P2,#00H
RET

DELAY_HIENTHI:
    MOV          R1,#20
DEL1:
    LCALL        HIENTHI
    DJNZ         R1,DEL1
RET

DELAY510US:
    MOV         78H,#255
    DJNZ        78H,$
RET

MA7447:
    DB    0F0H,0F1H,0F2H,0F3H,0F4H,0F5H,0F6H,0F7H,0F8H,0F9H
END